FINISH

/CLEAR

/title, Bridge with harvester - Bendine

/nopr
/com, ! Places comments in the output

/PREP7

!Amplitude=1e-7
ebig=10e-3
ESIZE,ebig
R=1e8
! ====================================================
! Define problem Geometry
! ====================================================
! - Bridge

Lbr=1 ! Bridge Length

Hbr=0.005 ! Bridge Thickness
Wbr=300e-3 ! Bridge width

! - substrate Beam
Lb=100e-3 ! substrate Length
Hb=0.5e-3 ! substrate Thickness
Wb=20e-3
! substrate Width
! - Support Beam
Ls=20e-3 ! Support Length
Hs=70e-3 ! Support Thickness
Ws=Wb ! Support Width

! - TIP mass
Lm=15e-3 ! TIP mass Length
Hm=9.4e-3 ! TIP mass Thickness
Wm=20e-3 ! TIP mass Width

! - PZT Geometry (All PZTs QP16n)

Lp=85e-3 ! piezo Length
Hp=0.4e-3 ! piezo Thickness
Wp=20e-3 ! piezo Width

L1=0.1 ! Starting point of PZT from the left length

w1=0.1 ! starting point of pzt from the left width
Ld=L1+Lb-Lm ! starting point of Tip mass

! ====================================================
! Solid model
! ====================================================
! Beam
BLOCK,0,Lbr,0,Wbr,0,Hbr ! Create the Bridge

!!!!!!!!!!!! with Tip mass!!!!!!!!!!!!!!!!!!!!!!

BLOCK,L1,L1+Ls,w1,w1+Ws,0,-Hs ! Create the harvester
support
BLOCK,L1,L1+Lb,w1,w1+Wb,-Hs-Hb-HP,-Hs-Hp ! Create the harvester
substrate
BLOCK,L1,L1+Lp,w1,w1+Wp,-Hs-Hp,-Hs ! Create the piezo harvester

! tip mass
BLOCK,L1+Lb-Lm,L1+Lb,w1,w1+Wm,-Hs-Hp,-Hs-Hp+Hm ! Create top tip mass
!vglue, all

WPROTA,,,90
WPOFFS,,,L1
VSBW,ALL
WPOFFS,,,Ls
VSBW,ALL
WPOFFS,,,Lp-Ls
VSBW,ALL
!WPOFFS,,,Ld
!VSBW,ALL
WPCSYS,,0

WPROTA,,-90,
WPOFFS,,,w1
VSBW,ALL
WPOFFS,,,Ws
VSBW,ALL
WPCSYS,,0

! - Material properties for Bridge

POISbr=0.3 ! Poisson's ration (Al) (0.35)
aldnsbr=2700 ! Density of Aluminium. (Al=2700, Dural(R)=2800)
EXYbr=69.5e+09

! - Material properties for substrate

POISs=0.3 ! Poisson's ration (Al) (0.35)
aldnss=7165 ! Density of Aluminium. (Al=2700, Dural(R)=2800)
EXYs=100e+09

! - Material properties for PVDF

s11=16.4e-12
s22=s11
s12=-5.74e-12
s13=-7.22e-12
s23=s13
s33=18.8e-12
s44=47.5e-12
s55=47.5e-12
s66=44.3e-12

pidns=7700 ! Density of PZT

d31=-179e-12 ! Piezoelectric strain coefficients, C/N
d32=-179e-12 ! Manufacturers data combined with PZT5A mat props
d33=350e-12
d24=584e-12
d16=584e-12

ept11=1730 ! Relative permittivity at constant stress

ept22=1730
ept33=1700

! ====================================================
! Meshed model
! ====================================================

! PZT-------------------------------------------------
et,1,SOLID5,3 ! 3-D piezoelectric element
MP,DENS,1,pidns
MP,PERX,1,ept11 ! Permittivity at constant stress
MP,PERY,1,ept22
MP,PERZ,1,ept33
tb,ANEL,1,,,1 ! Assembling elastic compliance matrix
tbda,1,s11,s12,s13
tbda,7,s22,s23
tbda,12,s33
tbda,16,s66
tbda,19,s55
tbda,21,s44
tb,PIEZ,1,,,1 ! Piezoelectric strain matrix
tbda,3,d31
tbda,6,d33
tbda,9,d32
tbda,14,d24
tbda,16,d16

! Bridge--------------------------------------------

ET,2,SOLID45
MP,EX,2,EXYbr
MP,PRXY,2,POISbr
MP,DENS,2,aldnsbr

! substrate-------------------------------------------

ET,2,SOLID45
MP,EX,3,EXYs
MP,PRXY,3,POISs
MP,DENS,3,aldnss

! Assigning mesh size and materials, mesh process initiation

! Global
ESIZE,ebig

VSEL,S,LOC,Z,0,Hbr ! Selecting bridge

VATT,2,1,2,0 ! Assigning bridge material properties
!VMESH,ALL

VSEL,S,LOC,Z,0,-Hs ! Selecting support

Vsel,r,loc,x,L1,L1+Ls
Vsel,r,loc,y,w1,w1+Ws
VATT,3,1,2,0 ! Assigning material properties
!VMESH,ALL
VSEL,S,LOC,Z,-Hs-Hp-Hb,-Hs-Hb ! Selecting substrate
Vsel,r,loc,x,L1,L1+Lb
Vsel,r,loc,y,w1,w1+Wb
VATT,3,1,2,0 ! Assigning material properties
!VMESH,ALL

VSEL,S,LOC,Z,-Hs-Hp,-Hs ! Selecting piezo

Vsel,r,loc,x,L1,L1+Lp
Vsel,r,loc,y,w1,w1+Wp
VATT,1,1,1,0 ! Assigning piezo material properties
!VMESH,ALL

VSEL,S,LOC,Z,-Hs,-Hs+Hm !Selecting top tip mass

Vsel,r,loc,x,L1+Lb-Lm,L1+Lb
Vsel,r,loc,y,w1,w1+Wm
VATT,2,1,2,0
!VMESH,ALL

!VSEL,s,LOC,Z,-Hs-Hb-Hp-Hm/2,-Hs-Hb-Hp !Selecting bottom tip mass

!Vsel,r,loc,x,L1+Lb-Lm,L1+Lb
!Vsel,r,loc,y,w1,w1+Wm
!VATT,2,1,2,0
!VMESH,ALL

ALLSEL
VPLOT
MSHAPE,0,3D
MSHKEY,1
numstr,node,12
VMESH,ALL

!----------------------
!Go and merge some nodes (eg. use glue layers of materials together)
!----------------------
nsel,s,LOC,Z,-Hs-Hp
nummrg,node,1e-5
nummrg,kp
nsel,all
nummrg,node,1e-5
nummrg,kp

N,1,L1+Ls+Lb+Lb/3,Wb/2,-Hs/2
N,2,L1+Ls+Lb+Lb/3,Wb/2, -Hs-Hp-Hb-Hs/2

ALLSEL,all

!---------------------------------
!Define upper electrodes on piezos
!---------------------------------
!Up1

nsel,s,LOC,Z,-Hs ! Selecting support

nsel,r,loc,x,L1+Ls,L1+Ls+Lp
nsel,r,loc,y,w1,w1+Wp
Nsel,A,node,,1
*get,Up1,node,0,num,min
cp,1,volt,all
d,Up1,VOLT,0
allsel

!Ub1

nSEL,S,LOC,Z,-Hs-Hp ! Selecting support

nsel,r,loc,x,L1+Ls,L1+Lp
nsel,r,loc,y,w1,w1+Wp
Nsel,A,node,,2
*get,Ub2,node,0,num,min
cp,2,volt,all
d,Ub2,VOLT,0
allsel

!----------------------
!added resistor
!----------------------

ET,3,CIRCU94,0 ! Set up the resistor

R,1,R
TYPE,3 $ REAL,1
!E,Up1,Ub2 ! Parallel the resistor to the
!E,n_max+1,n_max+2 ! electrodes of PZT
E,1,2 ! Parallel the resistor to the

!Force=node(Lbr/2,Wbr/2,Hbr)
disp=node(Lbr/2,Wbr/2,Hbr)
!clmp=node(0,Wb/2,Hb)

nsel,s,loc,x,0 ! Clamp left end of bimorph

nsel,a,loc,x,Lbr ! Clamp right end of bimorph
d,all,ux,0,,,,uy,uz ! Defines DOF constraints, clamp the end
nsel,all
allsel

!************************************************************
! Transient Analysis (MOVING LOAD)
!************************************************************

NDIV=10
PI=3.14
ALPHAD,4.886
BETAD,1.2433e-5
!
VELO=10
TIM=Lbr/NDIV/VELO
delta=1/100

*CREATE,FORCE
FDELE,ALL
DDELE,Up1,VOLT
TIME,ARG1
Force=node(ARG2,Wbr/2,Hbr)
amplitude=-10e2*cos(27*2*3.14*ARG1)
F,Force,FZ,amplitude
solve

*END
!

/SOLU
ANTYPE,4
TRNOPT,FULL,,DAMP
LUMPM,0
OUTRES,ALL,ALL

DELTIM,TIM ! Specifies the time step sizes

TINTP,,0.25,0.5,0.5
KBC,0 ! Ramped load step

*DO,K,1,100,1

*USE,FORCE,TIM*(K),(K)*delta

*ENDDO

Finish

/POST26 ! Enter time history

/grid,1
/axlab,x, Frequency Hz
/axlab,y, Voltage
!/GROPT,LOGY,ON
NSOL,2,Up1,volt,Z,Sensor1
NSOL,3,disp,U,Z,displacement
STORE,MERGE
XVAR,1
PLVAR,2,3

FINISH

!************************************************************
! Modal analysis Analysis
!************************************************************

/SOLU
ANTYPE,MODAL ! Modal analysis
nmodes = 10
modopt,LANB,nmodes ! Block Lanczos solver
mxpand,nmodes,,,yes ! Calculate element results and

DDELE,Up1,VOLT !DELETE VOLTAGW ON SENSORS ELECTRODE

!----------------------
!Clamp left end of beam
!----------------------
SOLVE

!*get,f1,mode,1,freq
FINISH